configure.ac 21 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594
  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ([2.59])
  4. AC_INIT(bind10-devel, 20100701, bind10-dev@isc.org)
  5. AC_CONFIG_SRCDIR(README)
  6. AM_INIT_AUTOMAKE
  7. AC_CONFIG_HEADERS([config.h])
  8. # Checks for programs.
  9. AC_PROG_CXX
  10. AC_PROG_LIBTOOL
  11. # Use C++ language
  12. AC_LANG([C++])
  13. # Identify the compiler: this check must be after AC_PROG_CXX and AC_LANG.
  14. AM_CONDITIONAL(USE_GXX, test "X${GXX}" = "Xyes")
  15. AC_CHECK_DECL([__SUNPRO_CC], [SUNCXX="yes"], [SUNCXX="no"])
  16. # Linker options
  17. # check -R rather than gcc specific -rpath to be as portable as possible.
  18. AC_MSG_CHECKING([whether -R flag is available in linker])
  19. LDFLAGS_SAVED="$LDFLAGS"
  20. LDFLAGS="$LDFLAGS -R/usr/lib"
  21. AC_TRY_LINK([],[],
  22. [ AC_MSG_RESULT(yes)
  23. rpath_available=yes
  24. ],[ AC_MSG_RESULT(no)
  25. rpath_available=no
  26. ])
  27. LDFLAGS=$LDFLAGS_SAVED
  28. # allow building programs with static link. we need to make it selective
  29. # because loadable modules cannot be statically linked.
  30. AC_ARG_ENABLE([static-link],
  31. AC_HELP_STRING([--enable-static-link],
  32. [build programs with static link [[default=no]]]),
  33. [enable_static_link=yes], [enable_static_link=no])
  34. AM_CONDITIONAL(USE_STATIC_LINK, test $enable_static_link = yes)
  35. # Check validity about some libtool options
  36. if test $enable_static_link = yes -a $enable_static = no; then
  37. AC_MSG_ERROR([--enable-static-link requires --enable-static])
  38. fi
  39. if test $enable_shared = no; then
  40. AC_MSG_ERROR([BIND 10 requires shared libraries to be built])
  41. fi
  42. # OS dependent configuration
  43. SET_ENV_LIBRARY_PATH=no
  44. ENV_LIBRARY_PATH=LD_LIBRARY_PATH
  45. case "$host" in
  46. *-solaris*)
  47. # Solaris requires special definitions to get some standard libraries
  48. # (e.g. getopt(3)) available with common used header files.
  49. CPPFLAGS="$CPPFLAGS -D_XPG4_2 -D__EXTENSIONS__"
  50. ;;
  51. *-apple-darwin*)
  52. # libtool doesn't work pefectly with Darwin: libtool embeds the
  53. # final install path in dynamic libraries and our loadable python
  54. # modules always refer to that path even if it's loaded within the
  55. # source tree. This prevents pre-install tests from working.
  56. # To work around this problem we explicitly specify paths to dynamic
  57. # libraries when we use them in the source tree.
  58. SET_ENV_LIBRARY_PATH=yes
  59. ENV_LIBRARY_PATH=DYLD_LIBRARY_PATH
  60. ;;
  61. esac
  62. AM_CONDITIONAL(SET_ENV_LIBRARY_PATH, test $SET_ENV_LIBRARY_PATH = yes)
  63. AC_SUBST(SET_ENV_LIBRARY_PATH)
  64. AC_SUBST(ENV_LIBRARY_PATH)
  65. m4_define([_AM_PYTHON_INTERPRETER_LIST], [python python3 python3.1])
  66. AC_ARG_WITH([pythonpath],
  67. AC_HELP_STRING([--with-pythonpath=PATH],
  68. [specify an absolute path to python executable when automatic version check (incorrectly) fails]),
  69. [python_path="$withval"], [python_path="auto"])
  70. if test "$python_path" = auto; then
  71. AM_PATH_PYTHON([3.1])
  72. else
  73. # Older versions of automake can't handle python3 well. This is an
  74. # in-house workaround for them.
  75. PYTHON=$python_path
  76. AC_SUBST(PYTHON)
  77. PYTHON_PREFIX='${prefix}'
  78. AC_SUBST(PYTHON_PREFIX)
  79. PYTHON_EXEC_PREFIX='$(exec_prefix)'
  80. AC_SUBST(PYTHON_EXEC_PREFIX)
  81. PYTHON_VERSION=[`$PYTHON -c "import sys; sys.stdout.write(sys.version[:3])"`]
  82. if test `echo "$PYTHON_VERSION >= 3.1" | bc` != 1 ; then
  83. AC_MSG_ERROR(["Python version too old: $PYTHON_VERSION, need 3.1 or higher"])
  84. fi
  85. AC_SUBST(PYTHON_VERSION)
  86. PYTHON_PLATFORM=`$PYTHON -c "import sys; print(sys.platform)"`
  87. AC_SUBST(PYTHON_PLATFORM)
  88. pythondir='${prefix}/lib/python'$PYTHON_VERSION'/site-packages'
  89. AC_SUBST(pythondir)
  90. pkgpythondir='${pythondir}/'$PACKAGE
  91. AC_SUBST(pkgpythondir)
  92. pyexecdir='${exec_prefix}/lib/python'$PYTHON_VERSION'/site-packages'
  93. AC_SUBST(pyexecdir)
  94. pkgpyexecdir='${pyexecdir}/'$PACKAGE
  95. AC_SUBST(pkgpyexecdir)
  96. fi
  97. # Check for python development environments
  98. if test -x ${PYTHON}-config; then
  99. PYTHON_INCLUDES=`${PYTHON}-config --includes`
  100. for flag in `${PYTHON}-config --ldflags`; do
  101. # add any '-L..." flags to PYTHON_LDFLAGS
  102. flag=`echo $flag | sed -ne 's/^\(\-L.*\)$/\1/p'`
  103. if test "X${flag}" != X; then
  104. PYTHON_LDFLAGS="$PYTHON_LDFLAGS ${flag}"
  105. fi
  106. done
  107. # on some platforms, ${PYTHON}-config --ldflags doesn't provide a -L
  108. # option while having the library under a non trivial directory.
  109. # as a workaround we try the "lib" sub directory under the common
  110. # prefix for this python.
  111. if test -z "${PYTHON_LDFLAGS}"; then
  112. PYTHON_LDFLAGS="-L`${PYTHON}-config --prefix`/lib"
  113. fi
  114. else
  115. if test "X$PYTHON_INCLUDES" = X -o "X$PYTHON_LDFLAGS" = X; then
  116. AC_MSG_WARN([${PYTHON}-config does not exist or is not executable, so we could not detect python development environment. Your system may require an additional package (e.g. "python3-dev"). Alternatively, if you are sure you have python headers and libraries, define PYTHON_INCLUDES and PYTHON_LDFLAGS and run this script.])
  117. fi
  118. fi
  119. # Some OSes including NetBSD don't install libpython.so in a well known path.
  120. # To avoid requiring dynamic library path with our python wrapper loadable
  121. # modules, we embed the path to the modules when possible. We do this even
  122. # when the path is known in the common operational environment (e.g. when
  123. # it's stored in a common "hint" file) for simplicity.
  124. if test $rpath_available = yes; then
  125. python_rpath=
  126. for flag in ${PYTHON_LDFLAGS}; do
  127. python_rpath="${python_rpath} `echo $flag | sed -ne 's/^\(\-L\)/-R/p'`"
  128. done
  129. PYTHON_LDFLAGS="${PYTHON_LDFLAGS} ${python_rpath}"
  130. fi
  131. AC_SUBST(PYTHON_INCLUDES)
  132. AC_SUBST(PYTHON_LDFLAGS)
  133. CPPFLAGS_SAVED="$CPPFLAGS"
  134. CPPFLAGS="$CPPFLAGS ${PYTHON_INCLUDES}"
  135. AC_CHECK_HEADERS([Python.h],, AC_MSG_ERROR([Missing Python.h]))
  136. CPPFLAGS="$CPPFLAGS_SAVED"
  137. # Check for python library. Needed for Python-wrapper libraries.
  138. LDFLAGS_SAVED="$LDFLAGS"
  139. LDFLAGS="$LDFLAGS $PYTHON_LDFLAGS"
  140. python_bin="python${PYTHON_VERSION}"
  141. AC_CHECK_LIB($python_bin, main, python_lib=$python_bin, python_lib=no)
  142. if test $python_lib != "no"; then
  143. PYTHON_LIB="-l$python_lib"
  144. fi
  145. AC_SUBST(PYTHON_LIB)
  146. LDFLAGS=$LDFLAGS_SAVED
  147. # TODO: check for _sqlite3.py module
  148. # Compiler dependent settings: define some mandatory CXXFLAGS here.
  149. # We also use a separate variable B10_CXXFLAGS. This will (and should) be
  150. # used as the default value for each specifc AM_CXXFLAGS:
  151. # AM_CXXFLAGS = $(B10_CXXFLAGS)
  152. # AM_CXXFLAGS += ... # add module specific flags
  153. # We need this so that we can disable some specific compiler warnings per
  154. # module basis; since AM_CXXFLAGS are placed before CXXFLAGS, and since
  155. # gcc's -Wno-XXX option must be specified after -Wall or -Wextra, we cannot
  156. # specify the default warning flags in CXXFLAGS and let specific modules
  157. # "override" the default.
  158. werror_ok=0
  159. # SunStudio compiler requires special compiler options for boost
  160. # (http://blogs.sun.com/sga/entry/boost_mini_howto)
  161. if test "$SUNCXX" = "yes"; then
  162. CXXFLAGS="$CXXFLAGS -library=stlport4 -features=tmplife -features=tmplrefstatic"
  163. fi
  164. # gcc specific settings:
  165. if test "X$GXX" = "Xyes"; then
  166. B10_CXXFLAGS="-Wall -Wextra -Wwrite-strings -Woverloaded-virtual -Wno-sign-compare"
  167. UNUSED_PARAM_ATTRIBUTE='__attribute__((unused))'
  168. # Certain versions of gcc (g++) have a bug that incorrectly warns about
  169. # the use of anonymous name spaces even if they're closed in a single
  170. # translation unit. For these versions we have to disable -Werror.
  171. CXXFLAGS_SAVED="$CXXFLAGS"
  172. CXXFLAGS="$CXXFLAGS $B10_CXXFLAGS -Werror"
  173. AC_MSG_CHECKING(for in-TU anonymous namespace breakage)
  174. AC_TRY_COMPILE([namespace { class Foo {}; }
  175. namespace isc {class Bar {Foo foo_;};} ],,
  176. [AC_MSG_RESULT(no)
  177. werror_ok=1
  178. B10_CXXFLAGS="$B10_CXXFLAGS -Werror"],
  179. [AC_MSG_RESULT(yes)])
  180. CXXFLAGS="$CXXFLAGS_SAVED"
  181. fi dnl GXX = yes
  182. AM_CONDITIONAL(GCC_WERROR_OK, test $werror_ok = 1)
  183. AC_DEFINE_UNQUOTED(UNUSED_PARAM, $UNUSED_PARAM_ATTRIBUTE, Define to compiler keyword indicating a function argument is intentionally unused)
  184. # produce PIC unless we disable shared libraries. need this for python bindings.
  185. if test $enable_shared != "no" -a "X$GXX" = "Xyes"; then
  186. B10_CXXFLAGS="$B10_CXXFLAGS -fPIC"
  187. fi
  188. AC_SUBST(B10_CXXFLAGS)
  189. # Checks for libraries.
  190. AC_SEARCH_LIBS(inet_pton, [nsl])
  191. AC_SEARCH_LIBS(recvfrom, [socket])
  192. # Checks for header files.
  193. # Checks for typedefs, structures, and compiler characteristics.
  194. AC_HEADER_STDBOOL
  195. AC_TYPE_SIZE_T
  196. AC_MSG_CHECKING(for sa_len in struct sockaddr)
  197. AC_TRY_COMPILE([
  198. #include <sys/types.h>
  199. #include <sys/socket.h>],
  200. [struct sockaddr sa; sa.sa_len = 0; return (0);],
  201. [AC_MSG_RESULT(yes)
  202. AC_DEFINE(HAVE_SA_LEN, 1, [Define to 1 if sockaddr has a sa_len member, and corresponding sin_len and sun_len])],
  203. AC_MSG_RESULT(no))
  204. AC_ARG_WITH(lcov,
  205. [ --with-lcov[=PROGRAM] enable gtest and coverage target using the specified lcov], lcov="$withval", lcov="no")
  206. AC_ARG_WITH(gtest,
  207. [ --with-gtest=PATH specify a path to gtest header files (PATH/include) and library (PATH/lib)],
  208. gtest_path="$withval", gtest_path="no")
  209. USE_LCOV="no"
  210. if test "$lcov" != "no"; then
  211. # force gtest if not set
  212. if test "$gtest_path" = "no"; then
  213. # AC_MSG_ERROR("lcov needs gtest for test coverage report")
  214. AC_MSG_NOTICE([gtest support is now enabled, because used by coverage tests])
  215. gtest_path="yes"
  216. fi
  217. if test "$lcov" != "yes"; then
  218. LCOV=$lcov
  219. else
  220. AC_PATH_PROG([LCOV], [lcov])
  221. fi
  222. if test -x "${LCOV}"; then
  223. USE_LCOV="yes"
  224. else
  225. AC_MSG_ERROR([Cannot find lcov.])
  226. fi
  227. # is genhtml always in the same directory?
  228. GENHTML=`echo "$LCOV" | sed s/lcov$/genhtml/`
  229. if test ! -x $GENHTML; then
  230. AC_MSG_ERROR([genhtml not found, needed for lcov])
  231. fi
  232. # GCC specific?
  233. CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
  234. LIBS=" $LIBS -lgcov"
  235. AC_SUBST(CPPFLAGS)
  236. AC_SUBST(LIBS)
  237. AC_SUBST(LCOV)
  238. AC_SUBST(GENHTML)
  239. fi
  240. AC_SUBST(USE_LCOV)
  241. #
  242. # Configure Boost header path
  243. #
  244. # If explicitly specified, use it.
  245. AC_ARG_WITH([boost-include],
  246. AC_HELP_STRING([--with-boost-include=PATH],
  247. [specify exact directory for Boost headers]),
  248. [boost_include_path="$withval"])
  249. # If not specified, try some common paths.
  250. if test -z "$with_boost_include"; then
  251. boostdirs="/usr/local /usr/pkg /opt /opt/local"
  252. for d in $boostdirs
  253. do
  254. if test -f $d/include/boost/shared_ptr.hpp; then
  255. boost_include_path=$d/include
  256. break
  257. fi
  258. done
  259. fi
  260. if test "${boost_include_path}" ; then
  261. BOOST_INCLUDES="-I${boost_include_path}"
  262. CPPFLAGS="$CPPFLAGS $BOOST_INCLUDES"
  263. fi
  264. AC_CHECK_HEADERS([boost/shared_ptr.hpp boost/foreach.hpp],,
  265. AC_MSG_ERROR([Missing required header files.]))
  266. AC_SUBST(BOOST_INCLUDES)
  267. #
  268. # Check availability of gtest, which will be used for unit tests.
  269. #
  270. if test "$gtest_path" != "no"
  271. then
  272. if test "$gtest_path" != "yes"; then
  273. GTEST_PATHS=$gtest_path
  274. if test -x "${gtest_path}/bin/gtest-config" ; then
  275. GTEST_CONFIG="${gtest_path}/bin/gtest-config"
  276. fi
  277. else
  278. AC_PATH_PROG([GTEST_CONFIG], [gtest-config])
  279. fi
  280. if test -x "${GTEST_CONFIG}" ; then :
  281. # using cppflags instead of cxxflags
  282. GTEST_INCLUDES=`${GTEST_CONFIG} --cppflags`
  283. GTEST_LDFLAGS=`${GTEST_CONFIG} --ldflags`
  284. GTEST_LDADD=`${GTEST_CONFIG} --libs`
  285. GTEST_FOUND="true"
  286. else
  287. AC_MSG_WARN([Unable to locate Google Test gtest-config.])
  288. if test -z "${GTEST_PATHS}" ; then
  289. GTEST_PATHS="/usr /usr/local"
  290. fi
  291. GTEST_FOUND="false"
  292. fi
  293. if test "${GTEST_FOUND}" != "true"; then
  294. GTEST_FOUND="false"
  295. for dir in $GTEST_PATHS; do
  296. if test -f "$dir/include/gtest/gtest.h"; then
  297. GTEST_INCLUDES="-I$dir/include"
  298. GTEST_LDFLAGS="-L$dir/lib"
  299. GTEST_LDADD="-lgtest"
  300. GTEST_FOUND="true"
  301. break
  302. fi
  303. done
  304. fi
  305. if test "${GTEST_FOUND}" != "true"; then
  306. AC_MSG_ERROR([Cannot find gtest in: $GTEST_PATHS])
  307. fi
  308. else
  309. GTEST_INCLUDES=
  310. GTEST_LDFLAGS=
  311. GTEST_LDADD=
  312. fi
  313. AM_CONDITIONAL(HAVE_GTEST, test $gtest_path != "no")
  314. AC_SUBST(GTEST_INCLUDES)
  315. AC_SUBST(GTEST_LDFLAGS)
  316. AC_SUBST(GTEST_LDADD)
  317. dnl check for pkg-config itself so we don't try the m4 macro without pkg-config
  318. AC_CHECK_PROG(HAVE_PKG_CONFIG, pkg-config, yes, no)
  319. if test "x$HAVE_PKG_CONFIG" = "xno" ; then
  320. AC_MSG_ERROR(Please install pkg-config)
  321. fi
  322. PKG_CHECK_MODULES(SQLITE, sqlite3 >= 3.3.9, enable_features="$enable_features SQLite3")
  323. # I can't get some of the #include <asio.hpp> right without this
  324. # TODO: find the real cause of asio/boost wanting pthreads
  325. # (this currently only occurs for src/lib/cc/session_unittests)
  326. PTHREAD_LDFLAGS=
  327. AC_CHECK_LIB(pthread, pthread_create,[ PTHREAD_LDFLAGS=-lpthread ], [])
  328. AC_SUBST(PTHREAD_LDFLAGS)
  329. #
  330. # ASIO: we extensively use it as the C++ event management module.
  331. #
  332. # Use local ASIO headers from ext
  333. #
  334. CPPFLAGS="$CPPFLAGS -I\$(top_srcdir)/ext/asio"
  335. #
  336. # kqueue portability: ASIO uses kqueue by default if it's available (it's
  337. # generally available in BSD variants). Unfortunately, some public
  338. # implementation of kqueue forces a conversion from a pointer to an integer,
  339. # which is prohibited in C++ unless reinterpret_cast, C++'s most evil beast
  340. # (and ASIO doesn't use it anyway) is used. This will cause build error for
  341. # some of our C++ files including ASIO header files. The following check
  342. # detects such cases and tells ASIO not to use kqueue if so.
  343. AC_CHECK_FUNC(kqueue, ac_cv_have_kqueue=yes, ac_cv_have_kqueue=no)
  344. if test "X$ac_cv_have_kqueue" = "Xyes"; then
  345. AC_MSG_CHECKING([whether kqueue EV_SET compiles in C++])
  346. AC_TRY_COMPILE([
  347. #include <sys/types.h>
  348. #include <sys/param.h>
  349. #include <sys/event.h>],
  350. [char* udata;
  351. EV_SET(NULL, 0, 0, 0, 0, 0, udata);],
  352. [AC_MSG_RESULT(yes)],
  353. [AC_MSG_RESULT([no, disable kqueue for ASIO])
  354. CPPFLAGS="$CPPFLAGS -DASIO_DISABLE_KQUEUE=1"
  355. ])
  356. fi
  357. # /dev/poll issue: ASIO uses /dev/poll by default if it's available (generally
  358. # the case with Solaris). Unfortunately its /dev/poll specific code would
  359. # trigger the gcc's "missing-field-initializers" warning, which would
  360. # subsequently make the build fail with -Werror. Further, older versions of
  361. # gcc don't provide an option to selectively suppress this warning.
  362. # So, for the moment, we simply disable the use of /dev/poll. Unless we
  363. # implement recursive DNS server with randomized ports, we don't need the
  364. # scalability that /dev/poll can provide, so this decision wouldn't affect
  365. # run time performance. Hpefully we can find a better solution or the ASIO
  366. # code will be updated by the time we really need it.
  367. AC_CHECK_HEADERS(sys/devpoll.h, ac_cv_have_devpoll=yes, ac_cv_have_devpoll=no)
  368. if test "X$ac_cv_have_devpoll" = "Xyes" -a "X$GXX" = "Xyes"; then
  369. CPPFLAGS="$CPPFLAGS -DASIO_DISABLE_DEV_POLL=1"
  370. fi
  371. AC_ARG_ENABLE(man, [AC_HELP_STRING([--enable-man],
  372. [regenerate man pages [default=no]])] ,enable_man=yes, enable_man=no)
  373. AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
  374. AC_ARG_ENABLE(install-configurations,
  375. [AC_HELP_STRING([--disable-install-configurations],
  376. [do not install configuration])], install_configurations=$enableval, install_configurations=yes)
  377. AM_CONDITIONAL(INSTALL_CONFIGURATIONS, test x$install_configurations = xyes || test x$install_configurations = xtrue)
  378. AC_CONFIG_FILES([Makefile
  379. src/Makefile
  380. src/bin/Makefile
  381. src/bin/bind10/Makefile
  382. src/bin/bind10/tests/Makefile
  383. src/bin/cmdctl/Makefile
  384. src/bin/cmdctl/tests/Makefile
  385. src/bin/bindctl/Makefile
  386. src/bin/bindctl/tests/Makefile
  387. src/bin/cfgmgr/Makefile
  388. src/bin/cfgmgr/tests/Makefile
  389. src/bin/host/Makefile
  390. src/bin/loadzone/Makefile
  391. src/bin/loadzone/tests/correct/Makefile
  392. src/bin/loadzone/tests/error/Makefile
  393. src/bin/msgq/Makefile
  394. src/bin/msgq/tests/Makefile
  395. src/bin/auth/Makefile
  396. src/bin/auth/tests/Makefile
  397. src/bin/auth/tests/testdata/Makefile
  398. src/bin/auth/benchmarks/Makefile
  399. src/bin/xfrin/Makefile
  400. src/bin/xfrin/tests/Makefile
  401. src/bin/xfrout/Makefile
  402. src/bin/xfrout/tests/Makefile
  403. src/bin/zonemgr/Makefile
  404. src/bin/zonemgr/tests/Makefile
  405. src/bin/usermgr/Makefile
  406. src/lib/Makefile
  407. src/lib/bench/Makefile
  408. src/lib/bench/example/Makefile
  409. src/lib/bench/tests/Makefile
  410. src/lib/cc/Makefile
  411. src/lib/cc/tests/Makefile
  412. src/lib/python/Makefile
  413. src/lib/python/isc/Makefile
  414. src/lib/python/isc/datasrc/Makefile
  415. src/lib/python/isc/cc/Makefile
  416. src/lib/python/isc/cc/tests/Makefile
  417. src/lib/python/isc/config/Makefile
  418. src/lib/python/isc/config/tests/Makefile
  419. src/lib/python/isc/log/Makefile
  420. src/lib/python/isc/log/tests/Makefile
  421. src/lib/python/isc/notify/Makefile
  422. src/lib/python/isc/notify/tests/Makefile
  423. src/lib/config/Makefile
  424. src/lib/config/tests/Makefile
  425. src/lib/config/testdata/Makefile
  426. src/lib/dns/Makefile
  427. src/lib/dns/tests/Makefile
  428. src/lib/dns/tests/testdata/Makefile
  429. src/lib/dns/python/Makefile
  430. src/lib/dns/python/tests/Makefile
  431. src/lib/exceptions/Makefile
  432. src/lib/exceptions/tests/Makefile
  433. src/lib/datasrc/Makefile
  434. src/lib/datasrc/tests/Makefile
  435. src/lib/xfr/Makefile
  436. ])
  437. AC_OUTPUT([src/bin/cfgmgr/b10-cfgmgr.py
  438. src/bin/cfgmgr/tests/b10-cfgmgr_test.py
  439. src/bin/cmdctl/cmdctl.py
  440. src/bin/cmdctl/run_b10-cmdctl.sh
  441. src/bin/cmdctl/tests/cmdctl_test
  442. src/bin/cmdctl/cmdctl.spec.pre
  443. src/bin/xfrin/tests/xfrin_test
  444. src/bin/xfrin/xfrin.py
  445. src/bin/xfrin/xfrin.spec.pre
  446. src/bin/xfrin/run_b10-xfrin.sh
  447. src/bin/xfrout/xfrout.py
  448. src/bin/xfrout/xfrout.spec.pre
  449. src/bin/xfrout/tests/xfrout_test
  450. src/bin/xfrout/run_b10-xfrout.sh
  451. src/bin/zonemgr/zonemgr.py
  452. src/bin/zonemgr/zonemgr.spec.pre
  453. src/bin/zonemgr/tests/zonemgr_test
  454. src/bin/zonemgr/run_b10-zonemgr.sh
  455. src/bin/bind10/bind10.py
  456. src/bin/bind10/tests/bind10_test
  457. src/bin/bind10/run_bind10.sh
  458. src/bin/bindctl/run_bindctl.sh
  459. src/bin/bindctl/bindctl-source.py
  460. src/bin/bindctl/tests/bindctl_test
  461. src/bin/loadzone/run_loadzone.sh
  462. src/bin/loadzone/tests/correct/correct_test.sh
  463. src/bin/loadzone/tests/error/error_test.sh
  464. src/bin/loadzone/b10-loadzone.py
  465. src/bin/usermgr/run_b10-cmdctl-usermgr.sh
  466. src/bin/usermgr/b10-cmdctl-usermgr.py
  467. src/bin/msgq/msgq.py
  468. src/bin/msgq/tests/msgq_test
  469. src/bin/msgq/run_msgq.sh
  470. src/bin/auth/auth.spec.pre
  471. src/bin/auth/spec_config.h.pre
  472. src/lib/config/tests/data_def_unittests_config.h
  473. src/lib/python/isc/config/tests/config_test
  474. src/lib/python/isc/cc/tests/cc_test
  475. src/lib/python/isc/log/tests/log_test
  476. src/lib/python/isc/notify/tests/notify_out_test
  477. src/lib/dns/gen-rdatacode.py
  478. src/lib/python/bind10_config.py
  479. src/lib/dns/tests/testdata/gen-wiredata.py
  480. src/lib/cc/session_config.h.pre
  481. src/lib/cc/tests/session_unittests_config.h
  482. ], [
  483. chmod +x src/bin/cmdctl/run_b10-cmdctl.sh
  484. chmod +x src/bin/xfrin/run_b10-xfrin.sh
  485. chmod +x src/bin/xfrout/run_b10-xfrout.sh
  486. chmod +x src/bin/zonemgr/run_b10-zonemgr.sh
  487. chmod +x src/bin/bind10/run_bind10.sh
  488. chmod +x src/bin/cmdctl/tests/cmdctl_test
  489. chmod +x src/bin/xfrin/tests/xfrin_test
  490. chmod +x src/bin/xfrout/tests/xfrout_test
  491. chmod +x src/bin/zonemgr/tests/zonemgr_test
  492. chmod +x src/bin/bindctl/tests/bindctl_test
  493. chmod +x src/bin/bindctl/run_bindctl.sh
  494. chmod +x src/bin/loadzone/run_loadzone.sh
  495. chmod +x src/bin/loadzone/tests/correct/correct_test.sh
  496. chmod +x src/bin/loadzone/tests/error/error_test.sh
  497. chmod +x src/bin/usermgr/run_b10-cmdctl-usermgr.sh
  498. chmod +x src/bin/msgq/run_msgq.sh
  499. chmod +x src/bin/msgq/tests/msgq_test
  500. chmod +x src/lib/dns/gen-rdatacode.py
  501. chmod +x src/lib/dns/tests/testdata/gen-wiredata.py
  502. ])
  503. AC_OUTPUT
  504. dnl Print the results
  505. dnl
  506. cat > config.report << END
  507. BIND 10 source configure results:
  508. -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  509. Package:
  510. Name: $PACKAGE_NAME
  511. Version: $PACKAGE_VERSION
  512. Flags:
  513. DEFS: $DEFS
  514. CPPFLAGS: $CPPFLAGS
  515. CXXFLAGS: $CXXFLAGS
  516. B10_CXXFLAGS: $B10_CXXFLAGS
  517. dnl includes too
  518. Python: ${PYTHON_INCLUDES}
  519. ${PYTHON_LDFLAGS}
  520. ${PYTHON_LIB}
  521. SQLite: $SQLITE_CFLAGS
  522. $SQLITE_LIBS
  523. Features:
  524. $enable_features
  525. Developer:
  526. Google Tests: $gtest_path
  527. Code Coverage: $USE_LCOV
  528. Generate Manuals: $enable_man
  529. END
  530. cat config.report
  531. cat <<EOF
  532. Now you can type "make" to build BIND 10
  533. EOF